/* convert_to_iic.aml                                 trz 17-nov-98
/*
/* covertype coverage into IIC interchange format 
/*

&args working_dir

&workspace %working_dir%

&if [exists cover_iic -cover] &then kill cover_iic
copy cover cover_iic


/* drop existing coverage items which are not needed
dropitem cover_iic.pat cover_iic.pat cover
dropitem cover_iic.pat cover_iic.pat split-id
dropitem cover_iic.pat cover_iic.pat akey

/* add the new IIC items
additem cover_iic.pat cover_iic.pat cover_type 3 3 i 0 
additem cover_iic.pat cover_iic.pat cover_size 2 2 i 0
additem cover_iic.pat cover_iic.pat stocking 2 2 i 0
additem cover_iic.pat cover_iic.pat age 3 3 i 0
additem cover_iic.pat cover_iic.pat measure_year 4 4 i 0
additem cover_iic.pat cover_iic.pat site_index 3 3 i 0
additem cover_iic.pat cover_iic.pat site_species 3 3 i 0
additem cover_iic.pat cover_iic.pat administrator 2 2 i 0
additem cover_iic.pat cover_iic.pat recon_level 2 2 i 0
additem cover_iic.pat cover_iic.pat stand_id 30 30 c 0


connect oracle landdept/slc

/* set up relate to poly-file and age-file and covertype xref table
relate add pf_rel /frisdb/inventory!ine!poly-file,info,KEY,key,ORDERED,RO
relate add age_rel /frisdb/inventory!ine!age-file,info,KEY,key,ORDERED,RO
relate add cov_rel iic_cover_xref,oracle,COVER_TYPE,county_code,ORDERED,RO
relate add sp_rel iic_species_xref,oracle,SITE_SPECIES,county_code,ORDERED,RO

/* set up cursor on pat file for coverage 
cursor cov_cur declare cover_iic.pat info rw
cursor cov_cur open


/* loop though all cover records and set attributes

&messages &off

&do &while %:cov_cur.aml$next% 

    /***** get info from poly-file *****

    &sv :cov_cur.cover_type    = %:cov_cur.pf_rel//type% 
    &sv :cov_cur.cover_size    = %:cov_cur.pf_rel//size%
    &sv :cov_cur.stocking      = %:cov_cur.pf_rel//density%

    &sv measure_year           = [substr %:cov_cur.age_rel//age-date% 7 4]
    &if [null %measure_year%] &then &sv measure_year = 0
    &sv :cov_cur.measure_year  = %measure_year%

    /*  set stand age to current age
    &if %measure_year% = 0 &then &sv measure_year = [date -year] 
    &sv :cov_cur.age           = %:cov_cur.age_rel//age-measured% +~
                                ( [date -year] - %measure_year% )
 
    &sv :cov_cur.site_index    = %:cov_cur.pf_rel//site-index%
    &sv :cov_cur.site_species  = %:cov_cur.pf_rel//site-idx-sp%
    &sv :cov_cur.administrator = 2
    &sv :cov_cur.recon_level   = %:cov_cur.pf_rel//recon%
    &sv :cov_cur.stand_id      = %:cov_cur.pf_rel//key%

    /***** Translate county attributes to IIC codes *****

    /* covertype
    cursor cov_cur relate cov_rel first
    &sv :cov_cur.cover_type = %:cov_cur.cov_rel//iic_code%

    /* size class
    &select %:cov_cur.cover_size%
      &when 1,2,3
            &sv :cov_cur.cover_size = 1
      &when 4
            &sv :cov_cur.cover_size = 2
      &when 5,6,7,8
            &sv :cov_cur.cover_size = 3
      &otherwise
            &sv :cov_cur.cover_size = 0
    &end

    /* stocking
    &select %:cov_cur.stocking%
      &when 0
            &sv :cov_cur.stocking = 1
      &when 1
            &sv :cov_cur.stocking = 2
      &when 2,3,4
            &sv :cov_cur.stocking = 3
      &otherwise
            &sv :cov_cur.stocking = 0
    &end

    /* site index species
    cursor cov_cur relate sp_rel first
    &sv :cov_cur.site_species = %:cov_cur.sp_rel//iic_code%

    /* recon level
    &select %:cov_cur.recon_level%
      &when 3,4,5,6
            &sv :cov_cur.recon_level = 1
      &when 0,1,2,7,8
            &sv :cov_cur.recon_level = 2
      &otherwise
            &sv :cov_cur.recon_level = 0
    &end

    cursor cov_cur next
&end

&messages &on

cursor cov_cur close
cursor cov_cur remove

disconnect oracle

/* drop remaining unneeded info items
dropitem cover_iic.pat cover_iic.pat tileid
dropitem cover_iic.pat cover_iic.pat poly-id
dropitem cover_iic.pat cover_iic.pat key

&return